buildscript {
	repositories {
		maven {
			name = "Fabric"
			url = "https://maven.fabricmc.net/"
			content {
				includeGroup "net.fabricmc"
				includeGroup "fabric-loom"
			}
		}
		mavenCentral()
	}
	dependencies {
		classpath "fabric-loom:fabric-loom.gradle.plugin:1.1.14"
	}
}

apply plugin: "fabric-loom"

java.toolchain.languageVersion = JavaLanguageVersion.of(17)
java.withSourcesJar()
tasks.withType(JavaCompile) {
	options.encoding = "UTF-8"
	options.release = 17
}

repositories {
	mavenCentral()

	maven {
		url = "https://maven.terraformersmc.com/releases/"
		content {
			includeGroup "com.terraformersmc"
		}
	}
}

dependencies {
	minecraft "com.mojang:minecraft:1.20.1"
	mappings "net.fabricmc:yarn:1.20.1+build.2"
	modApi "net.fabricmc:fabric-loader:0.14.21"
	modApi "net.fabricmc.fabric-api:fabric-api:0.83.1+1.20.1"

	implementation "com.google.code.findbugs:jsr305:3.0.2"

	//modRuntimeOnly "com.terraformersmc:modmenu:7.2.1" //REMAP FAILURES?????
}

loom {
	mixin {
		defaultRefmapName = "templates.refmap.json" //see templates.mixins.json. I just like to always specify the name
	}
}

processResources {
	inputs.property "version", project.version
	filesMatching("**/fabric.mod.json") {
		expand "version": project.version
	}
}

jar {
	from "LICENSE"
}
